VB- und JScript zusammenführen

Stefan_G.

Mitglied
Dabei seit
25.04.03
Beiträge
3.273
Standort
Nürnberg
Trophäen
Überblick verloren :-(
#1
Hallo,

Frage an alle Scripter:

Das Script, das Bilderendungen von JPG nach jpg umwandelt, läuft bei mir sehr gut als JScript:
Code:
//FFSubmenu=Umbenennen
//FFName=Extension Lowercase

var fso = new ActiveXObject("Scripting.FileSystemObject");
var   path,nn,on,i,l=FF_GetImageCount();
for(i=0; i<l; i++)
   {
   FF_SetProgress(i,l-1);
   on = FF_GetImageName(i);
   path = SplitPath(on);
   nn = path.dir + "\\" + path.file + path.ext.toLowerCase();
   fso.MoveFile(on,nn);
   }

// liefert Verzeichnis mit abschließendem Backslash,
// Dateinamen und Erweiterung mit einleitendem Punkt
function SplitPath(path)
   {
   var   result = new Object();
   result.dir = fso.GetParentFolderName(path) + "\\";
   result.file = fso.GetBaseName(path);
   result.ext = "." + fso.GetExtensionName(path);
   return result;
   }
Zum Einlesen der Bilder von meiner Casio mit FixFoto verwende ich folgendes VBScript:
Code:
'Dieses Skript wird auf jedes direkt von der Kamera aus kopierte / verschobene Bild ausgeführt
'Funktionen:
' - als Fotograf wird der Name eingetragen
' - ein Copyrightvermerk wird aus dem Bilddatum (Jahr) und dem Namen zusammengesetzt
' - falls von der Kamera unterstützt, wird das Bild Verlustfrei gedreht
Dim Datei, Dateiname, Extension, Pfad, Datum, Hersteller, v1, v2, Make
Dim Verzeichnis, Jahr, Monat, Tag, Orientation, Name
Datei = FF_GetImageName(0)
SplitPath Datei, , Dateiname, Extension
if FF_LoadExif(Datei) then                        'nur wenn auch Exif- Daten vorhanden sind weitermachen
  Name = "STEFAN GRÖTSCH"
  Datum = FF_GetExifTag("DateTime")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeOriginal")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeDigitized")
  if Datum = "" then Datum = Year(Now)      'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
  v1 = split(Datum, " ", -1)
  v2 = split(v1(0), ":", -1)
  Jahr = v2(0)
  Monat = v2(1)
  Tag = v2(2)
  FF_SetExifTag "Artist", Name
  FF_SetExifTag "Copyright1","© " + Jahr + " " + Name
  FF_SetExifTag "Copyright2", " >>> [url]www.stefan-groetsch.de.vu[/url] <<<"
  FF_SetExifTag "UserComment","Eingelesen und optimiert mit FixFoto, DAS Programm für Digitalfotos (siehe: [url]www.j-k-s.com[/url]); Read and optimized by FixFoto, THE software for digital images (see: [url]www.j-k-s.com[/url])"
  FF_SaveExif Datei
  
  'Das Bild Verlustfrei Drehen um 90 oder 270 Grad (falls von der Kamera unterstützt)
  Orientation = FF_GetExifTag("Orientation")
  if Orientation <> "" then
      'für die Kameras Casio QV4000 + QV5700
      if Orientation = "8" then              'Kamera nach links gekippt -> Drehung von 270 Grad
        FF_RotateFile Datei, 270
      elseif Orientation = "6" then        'Kamera nach rechts gekippt -> Drehung von 90 Grad
        FF_RotateFile Datei, 90
      end if
  end if
end if

'*********************************************************
' liefert Verzeichnis mit abschliessendem Backslash,      
' Dateinamen und Erweiterung mit einleitendem Punkt      
'*********************************************************
sub SplitPath(path, byref dirc, byref file, byref ext)
  Set fso = CreateObject("Scripting.FileSystemObject")
  dirc = fso.GetParentFolderName(path) & "\"
  file = fso.GetBaseName(path)
  ext = "." & fso.GetExtensionName(path)
  set fso = nothing
End Sub
Schafft es jemand beide Scripte ablauffähig in ein Script zusammenzuführen, damit schon beim Einlesen, Drehen der Bilder, Versehen mit Exif-Informationen etc. auch gleich die Dateiendung von JPG auf jpg geändert werden?

Wäre mir eine große Hilfe.

Gruß
Stefan
 

JKS

FF-Team
Dabei seit
06.06.02
Beiträge
6.712
#2
Probier mal diese Variante:

Code:
'Dieses Skript wird auf jedes direkt von der Kamera aus kopierte / verschobene Bild ausgeführt
'Funktionen:
' - als Fotograf wird der Name eingetragen
' - ein Copyrightvermerk wird aus dem Bilddatum (Jahr) und dem Namen zusammengesetzt
' - falls von der Kamera unterstützt, wird das Bild Verlustfrei gedreht
Dim Datei, Dateiname, Extension, Pfad, Datum, Hersteller, v1, v2, Make
Dim Verzeichnis, Jahr, Monat, Tag, Orientation, Name
Set fso = CreateObject("Scripting.FileSystemObject")
Datei = FF_GetImageName(0)
SplitPath Datei, Pfad, Dateiname, Extension
if FF_LoadExif(Datei) then                        'nur wenn auch Exif- Daten vorhanden sind weitermachen
  Name = "STEFAN GRÖTSCH"
  Datum = FF_GetExifTag("DateTime")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeOriginal")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeDigitized")
  if Datum = "" then Datum = Year(Now)      'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
  v1 = split(Datum, " ", -1)
  v2 = split(v1(0), ":", -1)
  Jahr = v2(0)
  Monat = v2(1)
  Tag = v2(2)
  FF_SetExifTag "Artist", Name
  FF_SetExifTag "Copyright1","© " + Jahr + " " + Name
  FF_SetExifTag "Copyright2", " >>> [url]www.stefan-groetsch.de.vu[/url] <<<"
  FF_SetExifTag "UserComment","Eingelesen und optimiert mit FixFoto, DAS Programm für Digitalfotos (siehe: [url]www.j-k-s.com[/url]); Read and optimized by FixFoto, THE software for digital images (see: [url]www.j-k-s.com[/url])"
  FF_SaveExif Datei
  fso.MoveFile Datei,Pfad & "\" & Dateiname & LCase(Extension)
  
  'Das Bild Verlustfrei Drehen um 90 oder 270 Grad (falls von der Kamera unterstützt)
  Orientation = FF_GetExifTag("Orientation")
  if Orientation <> "" then
      'für die Kameras Casio QV4000 + QV5700
      if Orientation = "8" then              'Kamera nach links gekippt -> Drehung von 270 Grad
        FF_RotateFile Datei, 270
      elseif Orientation = "6" then        'Kamera nach rechts gekippt -> Drehung von 90 Grad
        FF_RotateFile Datei, 90
      end if
  end if
end if
Set fso = nothing

'*********************************************************
' liefert Verzeichnis mit abschliessendem Backslash,      
' Dateinamen und Erweiterung mit einleitendem Punkt      
'*********************************************************
sub SplitPath(path, byref dirc, byref file, byref ext)
  dirc = fso.GetParentFolderName(path) & "\"
  file = fso.GetBaseName(path)
  ext = "." & fso.GetExtensionName(path)
End Sub
 

Stefan_G.

Mitglied
Dabei seit
25.04.03
Beiträge
3.273
Standort
Nürnberg
Trophäen
Überblick verloren :-(
#3
Hallo Joachim,

danke für die schnelle Script-Lieferung. Hab es getestet.

Einziger "Fehler": wird ein Bild gedreht, bleibt die Endung bei JPG.
Hier ein Screenshot zur Verdeutlichung:


Gruß
Stefan
 

JKS

FF-Team
Dabei seit
06.06.02
Beiträge
6.712
#4
Eine Zeile verschoben:

Code:
'Dieses Skript wird auf jedes direkt von der Kamera aus kopierte / verschobene Bild ausgeführt
'Funktionen:
' - als Fotograf wird der Name eingetragen
' - ein Copyrightvermerk wird aus dem Bilddatum (Jahr) und dem Namen zusammengesetzt
' - falls von der Kamera unterstützt, wird das Bild Verlustfrei gedreht
Dim Datei, Dateiname, Extension, Pfad, Datum, Hersteller, v1, v2, Make
Dim Verzeichnis, Jahr, Monat, Tag, Orientation, Name
Set fso = CreateObject("Scripting.FileSystemObject")
Datei = FF_GetImageName(0)
SplitPath Datei, Pfad, Dateiname, Extension
if FF_LoadExif(Datei) then                        'nur wenn auch Exif- Daten vorhanden sind weitermachen
  Name = "STEFAN GRÖTSCH"
  Datum = FF_GetExifTag("DateTime")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeOriginal")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeDigitized")
  if Datum = "" then Datum = Year(Now)      'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
  v1 = split(Datum, " ", -1)
  v2 = split(v1(0), ":", -1)
  Jahr = v2(0)
  Monat = v2(1)
  Tag = v2(2)
  FF_SetExifTag "Artist", Name
  FF_SetExifTag "Copyright1","© " + Jahr + " " + Name
  FF_SetExifTag "Copyright2", " >>> [url]www.stefan-groetsch.de.vu[/url] <<<"
  FF_SetExifTag "UserComment","Eingelesen und optimiert mit FixFoto, DAS Programm für Digitalfotos (siehe: [url]www.j-k-s.com[/url]); Read and optimized by FixFoto, THE software for digital images (see: [url]www.j-k-s.com[/url])"
  FF_SaveExif Datei
  
  'Das Bild Verlustfrei Drehen um 90 oder 270 Grad (falls von der Kamera unterstützt)
  Orientation = FF_GetExifTag("Orientation")
  if Orientation <> "" then
      'für die Kameras Casio QV4000 + QV5700
      if Orientation = "8" then              'Kamera nach links gekippt -> Drehung von 270 Grad
        FF_RotateFile Datei, 270
      elseif Orientation = "6" then        'Kamera nach rechts gekippt -> Drehung von 90 Grad
        FF_RotateFile Datei, 90
      end if
  end if
  fso.MoveFile Datei,Pfad & "\" & Dateiname & LCase(Extension)
end if
Set fso = nothing

'*********************************************************
' liefert Verzeichnis mit abschliessendem Backslash,      
' Dateinamen und Erweiterung mit einleitendem Punkt      
'*********************************************************
sub SplitPath(path, byref dirc, byref file, byref ext)
  dirc = fso.GetParentFolderName(path) & "\"
  file = fso.GetBaseName(path)
  ext = "." & fso.GetExtensionName(path)
End Sub
 

W.P.

Mitglied
Dabei seit
16.10.02
Beiträge
5.099
Standort
Anzing BY
#6
Nur so ein Gedanke,
wenn das Bild nur von der Kamera geholt wird, warum wird dann nicht vorher das Änderungsdatum der Datei geholt, falls kein EXIF enthalten ist?

Gemeint ist diese Stelle:
Code:
  if Datum = "" then Datum = FF_GetExifTag("DateTimeOriginal")
  if Datum = "" then Datum = FF_GetExifTag("DateTimeDigitized")
  if Datum = "" then Datum = Year(Now)      'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
Wie gesagt, nur so ein Gedanke zur Anregung...

Schönen Gruß,

Werner.
 

Stefan_G.

Mitglied
Dabei seit
25.04.03
Beiträge
3.273
Standort
Nürnberg
Trophäen
Überblick verloren :-(
#7
Hallo Werner,

das ist ein guter Gedanke, da unser Digifoto in der Arbeit kein Datumsexif hat und wir die Fotos zu Beweiszwecken brauchen. Normalerweise werden die Fotos gleich nach Rückkehr an den PC eingelesen. Der Einbau Deiner Funktion wäre deshalb wirklich interessant.

Da ich absoluter Script-Laie bin, kannst Du das Script mal insgesamt hier veröffentlichen, dann könnte ich es einmal testen. Kann aber etwas dauern. Eilt also nicht.

Gruß
Stefan
 

W.P.

Mitglied
Dabei seit
16.10.02
Beiträge
5.099
Standort
Anzing BY
#8
Code:
'Dieses Skript wird auf jedes direkt von der Kamera aus kopierte / verschobene Bild ausgeführt
'Funktionen:
' - als Fotograf wird der Name eingetragen
' - ein Copyrightvermerk wird aus dem Bilddatum (Jahr) und dem Namen zusammengesetzt
' - falls von der Kamera unterstützt, wird das Bild Verlustfrei gedreht

Option Explicit

Dim Datei
Dim oDatei
Dim Dateiname
Dim Extension
Dim Pfad

Dim Datum
Dim Hersteller
Dim v1
Dim v2
Dim Make

Dim Verzeichnis
Dim Jahr
Dim Monat
Dim Tag
Dim Orientation
Dim Name

Dim fso

Set fso = CreateObject("Scripting.FileSystemObject")

Datei = FF_GetImageName(0)
SplitPath Datei, Pfad, Dateiname, Extension

'nur wenn auch Exif-Daten vorhanden sind weitermachen
If FF_LoadExif(Datei) Then
    Name = "STEFAN GRÖTSCH"
    Datum = FF_GetExifTag("DateTime")
    
    If Datum = "" Then Datum = FF_GetExifTag("DateTimeOriginal")
    If Datum = "" Then Datum = FF_GetExifTag("DateTimeDigitized")
    'Datum von Dateidatum holen
    If Datum = "" Then
        Set oDatei = fso.GetFile(Datei)
        'Datum der letzten Änderung(idR Aufnahmedatum wenn unbearbeitet von Kamera transferiert)
        Datum = CStr(Year(oDatei.DateLastModified))

        'Anm: DateCreated kann falschen Zeitpunkt anzeigen, da bereits die kopierte Datei diesen Wert
        'verändert, außerdem ist er auf der Karte meist nicht vermerkt (FAT16)

        Set oDatei = Nothing
    End If
    'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
    'Anm: Sollte theoretisch nie mehr erreicht werden!
    If Datum = "" Then Datum = CStr(Year(Now))
    
    v1 = Split(Datum, " ", -1)
    v2 = Split(v1(0), ":", -1)
    Jahr = v2(0)
    Monat = v2(1)
    Tag = v2(2)
    
    FF_SetExifTag "Artist", Name
    FF_SetExifTag "Copyright1", "© " & Jahr & " " & Name
    FF_SetExifTag "Copyright2", " >>> [url]www.stefan-groetsch.de.vu[/url] <<<"
    FF_SetExifTag "UserComment", "Eingelesen und optimiert mit FixFoto, DAS Programm für Digitalfotos (siehe: [url]www.j-k-s.com[/url]); Read and optimized by FixFoto, THE software for digital images (see: [url]www.j-k-s.com[/url])"
    FF_SaveExif Datei
    
    'Das Bild Verlustfrei Drehen um 90 oder 270 Grad (falls von der Kamera unterstützt)
    Orientation = FF_GetExifTag("Orientation")
    If Orientation <> "" Then
        'für die Kameras Casio QV4000 + QV5700
        If Orientation = "8" Then              'Kamera nach links gekippt -> Drehung von 270 Grad
            FF_RotateFile Datei, 270
        ElseIf Orientation = "6" Then        'Kamera nach rechts gekippt -> Drehung von 90 Grad
            FF_RotateFile Datei, 90
        End If
    End If
    fso.MoveFile Datei, Pfad & "\" & Dateiname & LCase(Extension)
End If

Set fso = nothing

'*********************************************************
' liefert Verzeichnis mit abschliessendem Backslash,      
' Dateinamen und Erweiterung mit einleitendem Punkt      
'*********************************************************
Sub SplitPath(path, ByRef dirc, ByRef file, ByRef ext)
  dirc = fso.GetParentFolderName(path) & "\"
  file = fso.GetBaseName(path)
  ext = "." & fso.GetExtensionName(path)
End Sub
Wenn's hilft ;)
Zur besseren Lesbarkeit, die Formatierung verändert und um ein paar Kommentare ergänzt.

Frage zu "Orientation":
Wenn das Bild gedreht wurde, muss dann nicht auch der Wert auf Standard gesetzt (vermute: 0) werden? Bei jeden weiteren, theoretischen, Durchlauf wird das Bild momentan weitergedreht!

Schönen Gruß,

Werner.
 

Stefan_G.

Mitglied
Dabei seit
25.04.03
Beiträge
3.273
Standort
Nürnberg
Trophäen
Überblick verloren :-(
#9
Hallo Werner,

W. hat gesagt.:
... Bei jeden weiteren, theoretischen, Durchlauf wird das Bild momentan weitergedreht! ...
stimmt! Fällt aber nicht auf,da ich Bilder selten zwei Mal einlese.

Gruß
Stefan
 

W.P.

Mitglied
Dabei seit
16.10.02
Beiträge
5.099
Standort
Anzing BY
#11
Letzte Änderungen nach entsprechenden Wünschen:
Code:
'Dieses Skript wird auf jedes direkt von der Kamera aus kopierte / verschobene Bild ausgeführt
'Funktionen:
' - als Fotograf wird der Name eingetragen
' - ein Copyrightvermerk wird aus dem Bilddatum (Jahr) und dem Namen zusammengesetzt
' - falls von der Kamera unterstützt, wird das Bild Verlustfrei gedreht
' - falls Exif-Datum fehlt, wird es vom Dateiänderungs-Datum generiert
Option Explicit

Dim Datei
Dim oDatei
Dim Dateiname
Dim Extension
Dim Pfad
Dim Datum
Dim Hersteller
Dim Make

Dim Verzeichnis
Dim Jahr
Dim Orientation

Dim Name
Dim Copyright2

Dim fso

'*********************************************************
'* Hier kann das Skript angepasst werden!                *
'*********************************************************
Name = "VORNAME NACHNAME"
Copyright2 = "EVTL. HOMEPAGE ODER E-MAIL-ADRESSE DES FOTOGRAFEN"
'*********************************************************


Set fso = CreateObject("Scripting.FileSystemObject")

Datei = FF_GetImageName(0)
SplitPath Datei, Pfad, Dateiname, Extension

'nur wenn auch Exif-Daten vorhanden sind weitermachen
If FF_LoadExif(Datei) Then
    'Es heißt noch lange nicht, dass wenn LoadExif positiv ist, dass auch Exif-Daten vorhanden sind!
    If FF_HasExif Then
        Jahr = GetYearFromExifTime(FF_GetExifTag("DateTime"))
        If Len(Jahr) = 0 Then Jahr = GetYearFromExifTime(FF_GetExifTag("DateTimeOriginal"))
        If Len(Jahr) = 0 Then Jahr = GetYearFromExifTime(FF_GetExifTag("DateTimeDigitized"))
        
        'Datum von Dateidatum holen
        If Len(Jahr) = 0 Then
            Set oDatei = fso.GetFile(Datei)
            'Datum der letzten Änderung(idR Aufnahmedatum wenn unbearbeitet von Kamera transferiert)
            'DateCreated kann falschen Zeitpunkt anzeigen, da bereits die kopierte Datei diesen Wert
            'verändert, außerdem ist er auf der Karte meist nicht vermerkt (FAT16)
            Datum = CStr(Year(oDatei.DateLastModified)) & ":" & CStr(FormatNum(Month(oDatei.DateLastModified), 2)) & ":" & CStr(FormatNum(Day(oDatei.DateLastModified), 2))
            Datum = Datum & " " & CStr(FormatNum(Hour(oDatei.DateLastModified), 2)) & ":" & CStr(FormatNum(Minute(oDatei.DateLastModified), 2)) & ":" & CStr(FormatNum(Second(oDatei.DateLastModified), 2))
            FF_SetExifTag "DateTime", Datum
            FF_SetExifTag "DateTimeOriginal", Datum
            FF_SetExifTag "DateTimeDigitized", Datum
            Jahr = CStr(Year(oDatei.DateLastModified))
            Set oDatei = Nothing
        End If
        'wenn nichts anderes vorhanden ist, das aktuelle Jahr verwenden
        'Anm: Sollte theoretisch nie mehr erreicht werden!
        If Len(Jahr) = 0 Then Jahr = CStr(Year(Now))
        
        FF_SetExifTag "Artist", Name
        FF_SetExifTag "Copyright1","©" & Jahr & " " & Name
        FF_SetExifTag "Copyright2", Copyright2
        FF_SetExifTag "UserComment","Eingelesen und optimiert mit FixFoto, DAS Programm für Digitalfotos (siehe: [url]www.j-k-s.com[/url]); Read and optimized by FixFoto, THE software for digital images (see: [url]www.j-k-s.com[/url])"
        
        'Das Bild Verlustfrei Drehen um 90 oder 270 Grad (falls von der Kamera unterstützt)
        Orientation = FF_GetExifTag("Orientation")
        
        'Vorab schon mal Orientation setzen und Exif schreiben
        If ((Orientation = 8) Or (Orientation = 6)) Then FF_SetExifTag "Orientation", "1"
        FF_SaveExif Datei
        
        'Dann Anweisung umsetzen um Vorschaubild mitzudrehen
        'für die Kameras Casio QV4000 + QV5700
        If Orientation <> "" Then
            'Kamera nach links gekippt -> Drehung von 270 Grad
            If Orientation = "8" Then      
                FF_RotateFile Datei, 270
            'Kamera nach rechts gekippt -> Drehung von 90 Grad
            ElseIf Orientation = "6" Then
                FF_RotateFile Datei, 90
            End If
        End If
        
        fso.MoveFile Datei, Pfad & "\" & Dateiname & LCase(Extension)
    End If
End If

Set fso = nothing

'*********************************************************
' liefert Verzeichnis ohne abschliessendem Backslash,
' Dateinamen und Erweiterung mit einleitendem Punkt
'*********************************************************
Sub SplitPath(path, ByRef dirc, ByRef file, ByRef ext)
  dirc = fso.GetParentFolderName(path)
  file = fso.GetBaseName(path)
  ext = "." & fso.GetExtensionName(path)
End Sub
'*********************************************************
' liefert Jahr aus ExifZeit
'*********************************************************
Function GetYearFromExifTime(sDatum)
    GetYearFromExifTime = ""
    If Len(sDatum) > 0 Then
        If IsNumeric(Left(sDatum, 4)) Then
            GetYearFromExifTime = CStr(CLng(Left(sDatum, 4)))
        End If
    End If
End Function
'*********************************************************
' Formatiert Zahlen mit führenden Nullen
'*********************************************************
Function FormatNum(vNumber, lDigits)
    If Len(CStr(vNumber)) >= lDigits Then 
        FormatNum = vNumber
        Exit Function
    End If
    FormatNum = Right(String(lDigits, "0") & vNumber, lDigits)
End Function
Schönen Gruß,

Werner.
 

Stefan_G.

Mitglied
Dabei seit
25.04.03
Beiträge
3.273
Standort
Nürnberg
Trophäen
Überblick verloren :-(
#12
Hallo Werner,

hab's mit meinen neuen Urlaubsfotos der letzten zwei Wochen getestet. Läuft einwandfrei.
Stellst du es in den Downloadbereich? Dann kann ich unter Home » Skripte » Exif "einlese.zip" löschen. Kurze Info wäre gut.

Gruß
Stefan
 

W.P.

Mitglied
Dabei seit
16.10.02
Beiträge
5.099
Standort
Anzing BY
#13
Hallo,

Skript in den Downloadbereich überstellt, dabei nochmal minimal überarbeitet und mit zwei weiteren Dateien, die beim Installieren helfen sollen, gepackt.

Download über diesen Link möglich.

Schönen Gruß,

Werner.

Edit: 26.08.2004 - Dokumentation geringfügig angepasst!
 

masch

Mitglied
Dabei seit
24.03.04
Beiträge
31
#14
AW: VB- und JScript zusammenführen

Hallo,
dieses tolle Einlese-Skript funktioniert bei mir nicht mehr (FixFoto 2.79 Build 67).
Es meldet sich ein Fehler mit: Variable ist nicht definiert „FF_SaveExif“ bei XP und ME.
Bin leider kein Skriptler - bitte um Hilfe.

Schönen Gruß,
masch
 

W.P.

Mitglied
Dabei seit
16.10.02
Beiträge
5.099
Standort
Anzing BY
#15
AW: VB- und JScript zusammenführen

Hallo masch,
wird FF_SaveExif nicht etwa wieder kaputt sein? Du hast das Script schon aus FF heraus gestartet(via F10 (nur erstes selektiertes Bild) oder als Downloadscript eingebunden?) ?

Schönen Gruß,
Werner.
 

masch

Mitglied
Dabei seit
24.03.04
Beiträge
31
#16
AW: VB- und JScript zusammenführen

Hallo Wener,
es war "FixFoto 2.79 Build 64!" mit "FixFoto 2.79 Build 68" geht wieder alles!

Danke
Gruß
masch
 
Oben